Dell Command | Monitor Version 9.1 Reference Guide

'**********************************************************************

'*** Name: SampleSystemSummary.vbs

'*** Purpose: To check for BIOS Admin/Boot Password on a Dell OMCI client.

'*** Usage: cscript.exe //nologo SampleSystemSummary.vbs <systemname>

'*** This sample script is provided as an example only, and has not been

'*** tested, nor is warranted in any way by Dell; Dell disclaims any

'*** liability in connection therewith. Dell provides no technical

'*** support with regard to such scripting. For more information on WMI

'*** scripting, refer to applicable Microsoft documentation.

'**********************************************************************

Option Explicit 

'*** Declare variables

Dim strNameSpace 

Dim strComputerName 

Dim strClassName 

Dim strClassNameBIOS

Dim strKeyValueChassis 

Dim objInstance 

Dim ColSystem

Dim objWMIService

Dim strMessage

'*** Check that the right executable was used to run the script and that all parameters were passed

If (LCase(Right(WScript.FullName, 11)) = "wscript.exe" ) Or _

(Wscript.Arguments.Count < 1) Then 

Call Usage() 

WScript.Quit 

End If 

'*** Initialize variables

strNameSpace = "root/dcim/sysman"

strComputerName = WScript.Arguments(0) 

strClassName = "DCIM_Chassis" 

strClassNameBIOS = "DCIM_BIOSElement" 

strKeyValueChassis = "DCIM_Chassis"  

'*** Retrieve the instance of DCIM_Chassis class (there should only be 1 instance)

'*** Establish a connection to the dcim\sysman namespace

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate," &_

"AuthenticationLevel=pktprivacy}\\" & strComputerName & "\" &_ 

strNameSpace)

Set ColSystem=objWMIService.execquery ("Select * from " & strClassName)

For each objInstance in ColSystem 

if (objInstance.CreationClassName = strKeyValueChassis) Then 

strMessage = "Asset Tag: "

strMessage = strMessage & objInstance.Properties_.Item("Tag").Value 

strMessage = strMessage & vbCRLF & "Service Tag: "  

strMessage = strMessage & objInstance.Properties_.Item("ElementName").Value 

End if 

Next

'*** Retrieve all instances of DCIM_BIOSElement (there should only be 1 instance).

Set ColSystem=objWMIService.execquery ("Select * from " & strClassNameBIOS)

For each objInstance in ColSystem

strMessage = strMessage & vbCRLF & "BIOS Version: " 

strMessage = strMessage & objInstance.Properties_.Item("Version").Value 

Next 

'*** Display the results

WScript.Echo strMessage 

'*** Sub used to display the correct usage of the script

Sub Usage() 

Dim strMessage

strMessage = "incorrect syntax. You should run: " & vbCRLF & _

"cscript.exe //nologo SampleSystemSummary.vbs <systemname>" 

WScript.Echo strMessage

End Sub

'==========================================================================

' End

'==========================================================================